Rescue Media Builder Problem: Sprache und Tastaturlayout in US Englisch
Halllo,
ich habe das Problem, dass der Rescue Media Builder bei Auswahl eines WinPE-basierten Meduium ein Boot-Medium erzeugt, dass in komplett englischer Sprache läuft. Als Tastaturlayout wird auch US eingestellt. Ziemlich nervig, da der Media Builder keinerlei Einstellmöglichkeiten mehr besitzt.
Mein Betriebssystem ist Windows 10 Pro 64 Bit deutsch und ich benutze Aronis True Image 2016 (Build 6571).
Danke schonmal im Voraus.
"Das ist leider normal....."? Irgendwie haben die Macher ein völlig falsches Verständnis vom deutschen Recht. Ginge es nicht nur um ein paar lumpige Euro, hätte ich diesen Mist längst juristisch klären lassen. In der 2015er Version gabs das noch in deutsch. Ich fühle mich arglistig getäuscht, weil ich als deutscher Benutzer mit solch einer Praktik nicht rechnen muss. In der Beschreibung der 2016er Version wird das nicht erwähnt = juristisch betrachtet ein Produktmangel!
Nebenbei bemerkt: In der Version 6571 bleibt ein Datei-Backup permanent hängen. Abbrechen kann man das nicht, leiglich ein Neustart per Resettaste beendet den Spuk.
Liebe Acronis Macher, in meinem weitläufigen Bekanntenkreis werde ich dafür eindringlich werben, dass niemand mehr diesen Mist kauft. Werdet endlich wach, wir haben genug Mittelmäßigkeit auf dieser Welt und da muss man doch nicht auch noch mit unterdurchschnittlicher Software wertvolle Zeit vergeuden. Ernsthaft, über die Jahre ist True Image immer schlechter geworden, die unzähligen Klagen Netz zeigen das ebenfalls deutlich auf.
Gruß
Jürgen Imöhl
Danke für die schnellen Antworten.
Ich würde aber jetzt nicht soooo scharf hier schiessen. Man kann ja mit dem Rettungsmedium arbeiten. Aber ärgerlich ist so etwas schon, zumal die Rettungsmedien, die ich mit dem Rescue Media Buildern aus Acronis True Image 2015 und 2014 erzeugt habe, auch korekt in Deutsch waren.
Das Hängenbleiben beim Datei-Backup habe ich so nicht beobachten können, das läuft bei mir einwandfrei. Ich denke, dass Acronis das noch fixen wird.
Einen schönen Tag noch.
Na sicher müssen Sie nicht so scharf schießen, deshalb kam ja auf die unprofessionelle Antwort des Supports nichts mehr :-)
Sicherlich habe ich ein anderes Verständnis von einem guten Support. Fakt ist doch, dass es einen Mangel darstellt, den man beheben muss. Ich kenne einen Haufen Nutzer, die wirklich kaum englisch verstehen, schon gar nicht kennen sie sich mit einer englischen Tastaturbelegung aus. Ich finde es von elementarer Bedeutung, dass unerfahrene Benutzer gerade im Fall einer Backupsoftware sicher gehen können, dass sie beim Restore keine Fehler begehen. Ansonsten kann man sich ja auch eine kostenlose Software besorgen, aber selbst solche ist in vielen Fällen entsprechend übersetzt.
LG
Jürgen Imöhl
Hallo Jürgen Imöhl
Dieses Forum ist ein Benutzerforum, hier helfen zu 99,9% User User. MVPs sind erfahrende User und kein Support Personal.
Wegen dem Dateibackup, hätte ich mir ein Testbackup erstellt, dann alle Ordner des Dateibackups einzeln gesichert, um den Ordner mit dem störenden/ oder fehlerhaften Inhalt zu finden.
Bei Problemen kann man eine Supportanfrage machen:
https://www.acronis.com/de-de/support/contact-us.html
oder "Feedback" senden mit Beschwerden, Ideen, Verbesserungsvorschläge:
Hallo G. Uphoff,
es ist mir schon klar, dass das hier ein Nutzerforum ist. Trotzdem kann es nicht schaden, einen Sachmangel zu benennen, immerhin betrift es sicherlich unzählige Nutzer, die in der englischen Sparche nicht sonderlich sattelfest sind.
Übrigens schätze ich Ihren Tipp zum Dateibackup mehr als Scherz ein. Ich werde wohl kaum die Zeit investieren, 106 Ordner plus unzählige Unterordner auf diese Weise zu testen. Davon abgesehen, mit True Image 2015 gab es dieses Problem nicht. Trotzdem herzlichen Dank für Ihren Lösungsansatz.
FG
Jürgen Imöhl
Ich habe das Problem gelost!
Vorab: Es ist kein Problem, welches man Acronis vorwerfen kann!
Das Problem mit der falschen Sprache liegt einfach daran, dass das Windows ADK für Windows 10 nur eine US-amerikanische Version der WinPE-Umgebung (Datei: winpe.wim) installiert. Acronis fragt dieses Verzeichnis ab und kopiert sich die winpe.wim in ein Arbeitsverzeichnis und integriert darin TrueImage, das aber aufgrund der Sprachversion von winpe.wim natürlich auch in englisch integriert wird.
Das Problem habe ich nun folgerndermaßen gelöst:
Das installierte Windows ADK enthält glücklicherweise sämtliche Sprachpakete in einem speziellen Verzeichnis. Mit einer von mir erstellten Batchdatei, welches ich auf Basis der in der ADK vorliegenden Batches gschrieben habe, wird das gewünschte Sprachpaket in die bereits vorhandene us-englische winpe.wim integriert, die in diesem Sprachpaket enthaltene Sprache und das entsprechende Tastaturlayout als Standard gesetzt.
Die Batchdatei muss unter der Umgebung für Bereitstellungs- und Imageerstellungstools des ADK aufgerufen werden. Ihr erreicht diese unter Windows 10 durch "Startbutton anklicken" -> "Alle Apps" -> "Windows Kits" -> "Umgebung für Bereitstellungs- und Imageerstellungstools" -> "Mehr" -> "Als Administrator ausführen". Danach befindet Ihr Euch in dem entsprechenden Verzeichnis. Dort hinein solltet Ihr auch die Batchdatei kopieren.
Für die deutsche Sprache in einem 64-Bit Windows System sieht der Aufruf wie folgt aus:
ADK_WinPE_lp amd64 de-de C:\Wim,
wobei amd64 für die 64-Bit Variante und de-de für das deutsche Sprachpaket steht. C:\Wim steht für das Arbeitsverzeichnis, in der die für die Integration des Sprachpakets erforderlichen Dateien kopiert werden. Es kann auch ein anderes Verzeichnis gewählt werden, wobei aber zu beachten ist, dass dieses nicht bereits existiert. Denn die Batch löscht dieses Verzeichnis nach der erfolgreichen Integration automatisch.
Man hätte auch direkt in dem originalen ADK-Verzeichnis arbeiten können, aber ich ziehe es vor, lieber in einem Arbeitsverzeichnis zu arbeiten.
Hier nun die Batchdatei ADK_WimPE_lp.cmd:
----------------------------- Starts Here -----------------------
@echo off
setlocal
set EXITCODE=0
rem
rem Input validation
rem
if /i "%1"=="/?" goto usage
if /i "%1"=="" goto usage
if /i "%2"=="" goto usage
if /i "%~3" =="" goto usage
if /i not "%4"=="" goto usage
rem
rem Set environment variables for use in the script
rem
set WINPE_ARCH=%1
set SOURCE=%WinPERoot%\%WINPE_ARCH%
set WIMSOURCEPATH=%SOURCE%\en-us
set LPLANG=%2
set LPSOURCEPATH=%SOURCE%\WinPE_OCs\%LPLANG%
set WIMDESTPATH=%~3
set MOUNTDIR=%WIMDESTPATH%\mount
rem
rem Validate input architecture
rem
rem If the source directory as per input architecture does not exist,
rem it means the architecture is not present
rem
if not exist "%SOURCE%" (
echo ERROR: The following processor architecture was not found: %WINPE_ARCH%.
goto fail
)
rem
rem Validate input language
rem
rem If the language pack source directory as per input language does not exist,
rem it means the language is not present
rem
if not exist "%LPSOURCEPATH%\lp.cab" (
echo ERROR: The following language was not found: %LPLANG%.
goto fail
)
rem
rem Make sure the appropriate winpe.wim is present
rem
if not exist "%WIMSOURCEPATH%\winpe.wim" (
echo ERROR: WinPE WIM file does not exist: "%WIMSOURCEPATH%\winpe.wim".
goto fail
)
rem
rem Make sure the destination directory does not exist
rem
if exist "%WIMDESTPATH%" (
echo ERROR: Destination directory exists: "%WIMDESTPATH%".
goto fail
)
mkdir "%WIMDESTPATH%"
if errorlevel 1 (
echo ERROR: Unable to create destination: "%WIMDESTPATH%".
goto fail
)
echo.
echo ===================================================
echo Creating Windows PE customization working directory
echo.
echo %WIMDESTPATH%
echo ===================================================
echo.
if exist "%MOUNTDIR%" (
echo ERROR: Destination directory exists: "%MOUNTDIR%".
goto fail
)
mkdir "%MOUNTDIR%"
if errorlevel 1 (
echo ERROR: Unable to create directory: "%MOUNTDIR%".
goto fail
)
rem
rem Copy the WinPE WIM to the destination location
rem
copy "%WIMSOURCEPATH%\winpe.wim" "%WIMDESTPATH%\winpe.wim"
if errorlevel 1 (
echo ERROR: Unable to copy WinPE WIM: "%WIMSOURCEPATH%" to "%WIMDESTPATH%".
goto fail
)
echo.
echo ===================================================
echo Make Windows PE
echo.
echo %WIMDESTPATH%
echo ===================================================
echo.
rem
rem Mount the WinPE Image
rem
Dism /mount-image /imagefile:%WIMDESTPATH%\winpe.wim /index:1 /mountdir:%MOUNTDIR%
if errorlevel 1 (
echo ERROR: Unable to mount image.
)
rem
rem Add language pack into the mounted system image
rem
Dism /image:%MOUNTDIR% /add-package /packagepath:"%LPSOURCEPATH%\lp.cab"
if errorlevel 1 (
echo ERROR: Unable to add language pack.
)
rem
rem Set language as default language and keyboard layout
rem
Dism /image:%MOUNTDIR% /set-allintl:%LPLANG%
if errorlevel 1 (
echo ERROR: Unable to set default language.
)
rem
rem Unmount system files
rem
Dism /unmount-image /mountdir:%MOUNTDIR% /commit
if errorlevel 1 (
echo ERROR: Unable to unmount image.
)
rem
rem Backup the original ADK WInPE WIM and overwrite it with the new WinPE WIM
rem
rem Ready
rem
copy "%WIMSOURCEPATH%\winpe.wim" "%WIMSOURCEPATH%\winpe.org.%LPLANG%"
if errorlevel 1 (
echo ERROR: Unable to save WinPE WIM: "%WIMSOURCEPATH%\winpe.wim" to "%WIMDESTPATH%\winpe.org.%LPLANG%".
goto fail
)
copy "%WIMDESTPATH%\winpe.wim" "%WIMSOURCEPATH%\winpe.wim"
if errorlevel 1 (
echo ERROR: Unable to overwrite WinPE WIM: "%WIMSOURCEPATH%\winpe.wim" to "%WIMDESTPATH%\winpe.wim".
goto fail
)
if errorlevel 1 (
goto fail
)
rem
rem Remove work directories and files
rem
del "%WIMDESTPATH%\winpe.wim"
if errorlevel 1 (
echo ERROR: Unable to delete file: "%WIMDESTPATH%\winpe.wim".
goto fail
)
rmdir "%MOUNTDIR%"
if errorlevel 1 (
echo ERROR: Unable to delete directory: "%MOUNTDIR%".
goto fail
)
rmdir "%WIMDESTPATH%"
if errorlevel 1 (
echo ERROR: Unable to delete directory: "%WIMDESTPATH%".
goto fail
)
rem
rem Successful End
rem
:success
set EXITCODE=0
echo.
echo Success
echo.
goto cleanup
rem
rem usage help
rem
:usage
set EXITCODE=1
echo Creates the user definded language version of the WinPE.
echo.
echo ADK_WinPE_lp Architecture Language WorkingDirectory
echo.
echo Architecture
echo amd64 Makes an amd64 german WinPE image file and stores it in the ^<workingDirectory^>\amd64.
echo x86 Makes an x86 german WinPE image file and stores it in the ^<workingDirectory^>\x86.
echo arm Makes an arm german WinPE image file and stores it in the ^<workingDirectory^>\arm.
echo arm64 Makes an arm64 german WinPE image file and stores it in the ^<workingDirectory^>\arm64.
echo Note: ARM/ARM64 content may not be present in this ADK.
echo.
echo language
echo de-de Inserts the Germnan language pack
echo en-US Inserts the US-English language pack
echo fr-fr Inserts the French language pack
echo it-it Inserts the Italian language pack
echo .....
echo.
echo workingDirectory Creates the working directory at the specified location and deletes it after work is done.
echo.
echo Example: ADK_WinPE_lp amd64 de-de C:\Wim
pause
goto cleanup
rem
rem failure
rem
:fail
set EXITCODE=1
echo Failed!
goto cleanup
rem
rem Cleanup
rem
:cleanup
endlocal & exit /b %EXITCODE%
----------------------------- Ends Here -----------------------
Ich hätte Euch gerne das Script als Datei angehängt, was aber hier nicht angeboten wird. Aber Ihr könnt ja die Zeilen kopieren und in eine Textdatei anfügen. Diese nennt Ihr ADK_WinPE_lp.cmd.
Ich habe mir damit das deutsche Sprachpaket installiert.
Nach dieser Sprachpaketergänzung habe ich nochmal ein Rettungsmedium erstellt, das nun - sowohl in der Oberfläche von TrueImage als auch für das Tastaturlayout - in Deutsch vorliegt.
Hallo Hans-Hartwig Hein,
da haben Sie sich ja echt Mühe gemacht, tolle Arbeit.
Trotzdem bleibe ich dabei, es kann nicht Aufgabe eines Nutzers sein, die Software "gebrauchsfertig" zu machen. Ebenso unfertig ist ja auch der Rescue Media Builder unter Linux. Hier wird auch ein Tool in englischer Sprache erzeugt. Noch"bunter" wird es, wenn man ein Acronis Universal Restore-Medium erzeugt. Das ist dann auf deutsch - geht doch! Ich habe echt berechtigte Zweifel, ob Acronis noch weiß, was sie da tun.
Wie bereits erwähnt, es gibt mehrere Freewaretools, die das ähnlich gut machen und auf deutsch sind. Weshalb sollte man dann für eine Kaufsoftware bezahlen, die nicht fertig ist? Dass Acronis das kann, haben sie ja bis zur 2015er Version unter Beweis gestellt. Dass es das jetzt nicht mehr gibt, sehe ich als Vorsatz an und ist wahrscheinlich der Gewinnmaximierung geschuldet.
Davon abgesehen, Ihr Wissen in allen Ehren, die meisten User besitzen diese Kenntnisse nicht, diesbezüglich ist und bleibt Acronis in der Pflicht.
LG
Jürgen Imöhl
@Jürgen Imöhl: Das Script soll dem Benutzer die Arbeit abnehmen und das Leben leichter machen. Programmieren ist mein Hobby. Aber es ist tatsächlich so, dass man diese Klimmzüge bei TrueImage 2015 nicht machen musste. Welche Freeware-Tools kannst Du mir denn empfehlen? Ich habe zum Beispiel mal mit Macrium Reflect Free gearbeitet, aber das hat viele Features nicht, die Acronis hat.
Wenn ich die hier mal nennen darf .......
- Aomei Backupper_3.2_free - ........ Easeus Todo Backup Free_9.2_free - ......... - Paragon Backup & Recovery 14 Free -
Ergänzung:
Dass ein bootbarer USB-Stick in deutscher Sprache und deutschem Tastaturlayout unter Windows 10/64bit und installiertem ADK für Windows 10 ohne „Klimmzüge“ erstellt werden kann, beweist Paragon mit seinem Paragon Festplatten Manager™ 15 Professional. Ergo ist die Annahme, Acronis träfe kein Verschulden an nicht landesspezifischen USB-Sticks, widerlegt.
Diesbezüglich bleibe ich dabei, dass die Verantwortlichen bei Acronis bis heute kein gesteigertes Interesse daran haben, entsprechend passende Rettungsmedien bereitzustellen. Für eine Kaufsoftware ein No-Go und ein nicht erwarteter Sachmangel.
LG
Das habe ich auch festgestellt. Ich vermute, dass die sowas ähnliches wie meine Batchdatei auf ihr erstelltes WinPE (boot.wim) anwenden. Das könnte Acronis natürlich auch so machen und sie sollten es auf jeden Fall auch tun und ein Update ihres Rescue Media Builders herausbringen.
LG.