Rescue Media Builder Problem under Windows 10
Hello,
I have the problem, that the Rescue Media Builder is not able to create a WinPE Boot Media in german language. The program is in engllish and the keyboard layout is US English.
My OS is Windows 10 64 bit German and I use the rescue media builder from Acronis True Image 2016 Build 6571.
Thank You for your fast reply. I didn't use ADK. The Rescue Media Builder from ATI 2016 does not offer the possibility to choose a specific ADK (e.g. Windows 8.1 or Windows 7 ADK, 32 or 64 bit) like in earlier versions. It uses the WinPE environment from the installed operating system, in my case Windows 10 Pro X64 GERMAN. When I use the Acronis Rescue Media Builder from Acronis True Image 2015 the language and keyboard layout of the Boot Media are correctly german. So I think, that there is a problem with the Media Builder of Acronis 2016. I hope Acronis will fix this soon.
Have a good day.
The problem is, that the install routine of the ADK for Windows 10 only installs the US english version of the WinPE. So Acronis Rescue media builder is only able to add that environment, so that the program language and the keyboard layout are in US english.
Fortunately the installer also installs the language packs of the other languages in a specific folder, so that you are able to add the preferred language into the WinPE.
I have written a batch which adds a language pack of your choice into the ADK WinPE environment.
You can paste and insert the source code below into a new text-file with the name ADK_WinPE_lp.cmd.
For executing the batch you must go into the Deployment and Imaging Tools Environment of the ADK as administrator. You can do this by clicking on the start button. There you go to "All Apps", from there to "Windows Kits" and there you'll find the entry "Deployment and Imaging Tools Environment". There you do a right click and then in the context meu to "More" and there to "Run as Adminsitrator". DISM needs to be run as Adminstrator.
Now you are in the Deployment and Imaging Tools Environment as Adminsitrator.
If You have a 64-bit system and you want to add the german language for example you must enter this command:
ADK_WinPE_lp amd64 de-de C:\Wim
where amd64 is the variable for a 64-bit system, de-de the variable für the german language and keyboard layout and C:\Wim the working directory. I could have worked directly with the corresponding ADK WinPE directories, but I always prefer to work with copies of the original files. After success the batch makes a backup of the original wim file and then it overwrites this file with the new generated one.
You can enter ADK_WinPE_lp /? for help.
Now here is the source code for this batch:
----------------------------- Starts Here -----------------------
@echo off
setlocal
set EXITCODE=0
rem
rem Input validation
rem
if /i "%1"=="/?" goto usage
if /i "%1"=="" goto usage
if /i "%2"=="" goto usage
if /i "%~3" =="" goto usage
if /i not "%4"=="" goto usage
rem
rem Set environment variables for use in the script
rem
set WINPE_ARCH=%1
set SOURCE=%WinPERoot%\%WINPE_ARCH%
set WIMSOURCEPATH=%SOURCE%\en-us
set LPLANG=%2
set LPSOURCEPATH=%SOURCE%\WinPE_OCs\%LPLANG%
set WIMDESTPATH=%~3
set MOUNTDIR=%WIMDESTPATH%\mount
rem
rem Validate input architecture
rem
rem If the source directory as per input architecture does not exist,
rem it means the architecture is not present
rem
if not exist "%SOURCE%" (
echo ERROR: The following processor architecture was not found: %WINPE_ARCH%.
goto fail
)
rem
rem Validate input language
rem
rem If the language pack source directory as per input language does not exist,
rem it means the language is not present
rem
if not exist "%LPSOURCEPATH%\lp.cab" (
echo ERROR: The following language was not found: %LPLANG%.
goto fail
)
rem
rem Make sure the appropriate winpe.wim is present
rem
if not exist "%WIMSOURCEPATH%\winpe.wim" (
echo ERROR: WinPE WIM file does not exist: "%WIMSOURCEPATH%\winpe.wim".
goto fail
)
rem
rem Make sure the destination directory does not exist
rem
if exist "%WIMDESTPATH%" (
echo ERROR: Destination directory exists: "%WIMDESTPATH%".
goto fail
)
mkdir "%WIMDESTPATH%"
if errorlevel 1 (
echo ERROR: Unable to create destination: "%WIMDESTPATH%".
goto fail
)
echo.
echo ===================================================
echo Creating Windows PE customization working directory
echo.
echo %WIMDESTPATH%
echo ===================================================
echo.
if exist "%MOUNTDIR%" (
echo ERROR: Destination directory exists: "%MOUNTDIR%".
goto fail
)
mkdir "%MOUNTDIR%"
if errorlevel 1 (
echo ERROR: Unable to create directory: "%MOUNTDIR%".
goto fail
)
rem
rem Copy the WinPE WIM to the destination location
rem
copy "%WIMSOURCEPATH%\winpe.wim" "%WIMDESTPATH%\winpe.wim"
if errorlevel 1 (
echo ERROR: Unable to copy WinPE WIM: "%WIMSOURCEPATH%" to "%WIMDESTPATH%".
goto fail
)
echo.
echo ===================================================
echo Make Windows PE
echo.
echo %WIMDESTPATH%
echo ===================================================
echo.
rem
rem Mount the WinPE Image
rem
Dism /mount-image /imagefile:%WIMDESTPATH%\winpe.wim /index:1 /mountdir:%MOUNTDIR%
if errorlevel 1 (
echo ERROR: Unable to mount image.
)
rem
rem Add language pack into the mounted system image
rem
Dism /image:%MOUNTDIR% /add-package /packagepath:"%LPSOURCEPATH%\lp.cab"
if errorlevel 1 (
echo ERROR: Unable to add language pack.
)
rem
rem Set language as default language and keyboard layout
rem
Dism /image:%MOUNTDIR% /set-allintl:%LPLANG%
if errorlevel 1 (
echo ERROR: Unable to set default language.
)
rem
rem Unmount system files
rem
Dism /unmount-image /mountdir:%MOUNTDIR% /commit
if errorlevel 1 (
echo ERROR: Unable to unmount image.
)
rem
rem Backup the original ADK WInPE WIM and overwrite it with the new WinPE WIM
rem
rem Ready
rem
copy "%WIMSOURCEPATH%\winpe.wim" "%WIMSOURCEPATH%\winpe.org.%LPLANG%"
if errorlevel 1 (
echo ERROR: Unable to save WinPE WIM: "%WIMSOURCEPATH%\winpe.wim" to "%WIMDESTPATH%\winpe.org.%LPLANG%".
goto fail
)
copy "%WIMDESTPATH%\winpe.wim" "%WIMSOURCEPATH%\winpe.wim"
if errorlevel 1 (
echo ERROR: Unable to overwrite WinPE WIM: "%WIMSOURCEPATH%\winpe.wim" to "%WIMDESTPATH%\winpe.wim".
goto fail
)
if errorlevel 1 (
goto fail
)
rem
rem Remove work directories and files
rem
del "%WIMDESTPATH%\winpe.wim"
if errorlevel 1 (
echo ERROR: Unable to delete file: "%WIMDESTPATH%\winpe.wim".
goto fail
)
rmdir "%MOUNTDIR%"
if errorlevel 1 (
echo ERROR: Unable to delete directory: "%MOUNTDIR%".
goto fail
)
rmdir "%WIMDESTPATH%"
if errorlevel 1 (
echo ERROR: Unable to delete directory: "%WIMDESTPATH%".
goto fail
)
rem
rem Successful End
rem
:success
set EXITCODE=0
echo.
echo Success
echo.
goto cleanup
rem
rem usage help
rem
:usage
set EXITCODE=1
echo Creates the user definded language version of the WinPE.
echo.
echo ADK_WinPE_lp Architecture Language WorkingDirectory
echo.
echo Architecture
echo amd64 Makes an amd64 german WinPE image file and stores it in the ^<workingDirectory^>\amd64.
echo x86 Makes an x86 german WinPE image file and stores it in the ^<workingDirectory^>\x86.
echo arm Makes an arm german WinPE image file and stores it in the ^<workingDirectory^>\arm.
echo arm64 Makes an arm64 german WinPE image file and stores it in the ^<workingDirectory^>\arm64.
echo Note: ARM/ARM64 content may not be present in this ADK.
echo.
echo language
echo de-de Inserts the Germnan language pack
echo en-US Inserts the US-English language pack
echo fr-fr Inserts the French language pack
echo it-it Inserts the Italian language pack
echo .....
echo.
echo workingDirectory Creates the working directory at the specified location and deletes it after work is done.
echo.
echo Example: ADK_WinPE_lp amd64 de-de C:\Wim
pause
goto cleanup
rem
rem failure
rem
:fail
set EXITCODE=1
echo Failed!
goto cleanup
rem
rem Cleanup
rem
:cleanup
endlocal & exit /b %EXITCODE%
----------------------------- Ends Here -----------------------
Very handy indeed! I have not tested it, but will keep it in mind for others too!